/*
 To determine whether NEW files were added to a particular directory, this script will
 look for a project-level variable containing the last date-time the script was run and files were imported.
 If it isn't set, then we'll use a really old date by default. The variable will be set later
 in the script if any files were imported.

 Project-level variables are saved with a particular project.

 To delete the project-level variables, type "list;" in the Command Window, select the
 variable in the popup dialog, and delete it.
*/

// Local variable for last import date-time. Default it to old date
double dLastImpDateTime = date("01/01/1990 00:00:00");

// Update that variable from the project-level one if it exists
if (exist(CK_LAST_IMP_DATETIME, 4) == 4)
{
	dLastImpDateTime = CK_LAST_IMP_DATETIME;
}

// Get the folder to import files from allowing user to set the selected folder as the default for imports
// from this script from now on.
string sBasePath$;

// CK_DEF_IMP_FOLDER$ is a project level variable holding the default folder if one is set in a previous script run.
if (exist(CK_DEF_IMP_FOLDER$, 18))
{
	sBasePath$ = CK_DEF_IMP_FOLDER$;
}
else
{
	// A default folder was not previously set. Prompt user for folder to import from
	dlgPath sBasePath$ title:="Select the folder containing the data files you wish to import." showfiles:=1;


	// Ask user if they want to save this folder as the default for the script.
	// User clicks cancel, script execution stopped
	int nSaveDefault = 0;

	getyesno "Do you wish to save the selected folder as the default one for this script?" nSaveDefault "Save Default Folder?";

	// Set project-level variable for folder if they want to save it.
	if (nSaveDefault == 1)
	{
		CK_DEF_IMP_FOLDER$ = sBasePath$;
	}
}


// File extension for type of files to import
string sFileExt$ = "txt";

// String to hold list of filenames found. Each is separated by a CRLF.
string sFileNames$;

// Get all files in selected folder with specified file extention
// findfiles X-Function theoretically has a date filter but it is buggy.
findfiles path:=sBasePath$ ext:=sFileExt$ addpath:=1 fname:=sFileNames$;

// Now we can import the files that were found!!!

// Iterate through all individual file names in sFileNames$
int nTokens = sFileNames.GetNumTokens(CRLF);

int nNewCount = 0;
for (int ii = 1; ii <= nTokens; ii++)
{
	// Get the file from the list found by finefiles above.
	string sFile$ = sFileNames.GetToken(ii, CRLF)$;

	// Get it's modified date-time
	double dFileModDateTime = exist(sFile$,5);

	// Compare modifed time to last import date-time. If it's older, then skip the file
	if (dFileModDateTime <= dLastImpDateTime)
	{
		continue;
	}


//// NOW import the files here!!!
	impasc fname:=sFile$ orng:=<new>;
////


	nNewCount++;
}

// No new files found? Notify user and exit the script
if (nNewCount == 0)
{
	type -b "No new files were found to import in the selected folder.";

	return 0;
}

// Create/update the project-level variable. Can't assign @D directly- some sort of issue.
dLastImpDateTime = @D;
CK_LAST_IMP_DATETIME = dLastImpDateTime;

// Get the folder to import files from allowing user to set the selected folder as the default for imports
// from this script (for the current project) from now on.
string sBasePath$;

// CK_DEF_IMP_FOLDER$ is a project level variable holding the default folder if one is set in a previous script run.
if (exist(CK_DEF_IMP_FOLDER$, 18))
{
	sBasePath$ = CK_DEF_IMP_FOLDER$;
}
else
{
	// A default folder was not previously set. Prompt user for folder to import from
	dlgPath sBasePath$ title:="Select the folder containing the data files you wish to import." showfiles:=1;

	// Ask user if they want to save this folder as the default for the script.
	// User clicks cancel, script execution stopped
	int nSaveDefault = 0;

	getyesno "Do you wish to save the selected folder as the default one for this script?" nSaveDefault "Save Default Folder?";

	// Set project-level variable for folder if they want to save it.
	if (nSaveDefault == 1)
	{
		CK_DEF_IMP_FOLDER$ = sBasePath$;
	}
}


// File extension for type of files to import
string sFileExt$ = "txt";

// String to hold list of filenames found. Each is separated by a CRLF.
string sFileNames$;

// Get all files in selected folder with specified file extention
findfiles path:=sBasePath$ ext:=sFileExt$ addpath:=0 fname:=sFileNames$;


// Get number of filenames found
int nTokens = sFileNames.GetNumTokens(CRLF);

// Counter for number of new files
int nNewCount = 0;

// If 1 or more filesnames found, process them
if (nTokens > 0)
{
	// String array to hold list of previously imported files
	StringArray saPrevImps;

	// Build a string array of files previously imported into worksheets
	doc -e W {	// Use doc -ef W to limit to the current folder

		// Iterate layers in workbook
		for (int lay = 1; lay <= page.nlayers; lay++)
		{
			page.active = lay;
			saPrevImps.Add(page.info.system.import.filepath$);
		}
	}

	// Ititerate through all individual filenames in sFileNames$
	for (int ii = 1; ii <= nTokens; ii++)
	{
		// Build string for full file path and name
		string sFile$ = sBasePath$ + "\" + sFileNames.GetToken(ii, CRLF)$;

		// Search in the saPrevImps string array to see if the currently iterated filename is in it
		// If it is, then skip the filename
		if (saPrevImps.find(sFile$) > 0)
		{
			continue;
		}

		// The file hasn't been imported yet- so import it now!!!
		impasc fname:=sFile$ orng:=<new>;


		// Increment new file counter
		nNewCount++;
	}
}

// No new files found? Notify user and exit the script
if (nNewCount == 0)
{
	type -b "No new files were found to import from the selected Windows folder.";
}